quark/quarks
1
0
Fork 0
Code Issues Pull Requests Packages Projects Releases Wiki Activity

Initial checkin

Browse Source
This commit is contained in:
Stefan Reimer 2011-09-28 19:05:42 -07:00
commit 6418f36108
16 changed files with 910 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
games-rpg/gtkevemon-svn/Manifest Normal file
View File

@ -0,0 +1 @@
EBUILD gtkevemon-svn-9999-r1.ebuild 775 RMD160 9ba05704793e5051aead4a97d9f71de01382b4be SHA1 8fbf7bc35737eae303fed98accb6bff23b8a0c26 SHA256 c18743931a80b708e7cc925594a383b41d4111c453f48000f20b6853187128e3

28
games-rpg/gtkevemon-svn/gtkevemon-svn-9999-r1.ebuild Normal file
View File

@ -0,0 +1,28 @@
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
inherit eutils subversion
DESCRIPTION="GtkEveMon is a skill monitoring stand-alone application for GNU/Linux systems"
SRC_URI=""
# ESVN_REPO_URI="svn://svn.battleclinic.com/GTKEVEMon/trunk/gtkevemon/${PN%-svn}"
ESVN_REPO_URI="svn://svn.battleclinic.com/GTKEVEMon/trunk/gtkevemon"
ESVN_PROJECT="${PN%-svn}"
HOMEPAGE="http://gtkevemon.battleclinic.com"
KEYWORDS="~x86 ~amd64"
SLOT="0"
LICENSE="GPL-3"
IUSE=""
DEPEND=">=dev-cpp/gtkmm-2.12
>=dev-libs/libxml2-2.6.27"
RDEPEND="${DEPEND}"
src_install() {
exeinto /usr/bin
newexe src/${PN%-svn} ${PN%-svn}
newicon icon/${PN%-svn}.xpm ${PN%-svn}.xpm
newmenu icon/${PN%-svn}.desktop ${PN%-svn}.desktop
}

2
games-rpg/pyfa/Manifest Normal file
View File

@ -0,0 +1,2 @@
DIST pyfa-1.0-stable-RC1-src.tar.bz2 5572232 RMD160 16c52ee488951e7fd3a0241bfd8770a28a8c334a SHA1 f6945d6aa7a0861f770bfa70415025ac74d730db SHA256 f54038db30dccdf5de7c6c5729d0e3c92ac95daa9370e6642cf64a413147781e
EBUILD pyfa-1.0.ebuild 710 RMD160 c4c2e4d2796066446c6d293b469826f4b2bfb7c8 SHA1 ffb88e28ba90691930ae79af0c904f86c1b78288 SHA256 7fb07bda021dfbd9e1877eaf9bbba87563d3f98d030027cc9dd489a2e993f4f9

34
games-rpg/pyfa/pyfa-1.0.ebuild Normal file
View File

@ -0,0 +1,34 @@
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
EAPI=3
PYTHON_DEPEND="2:2.6"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="2.4"
inherit eutils
if [[ ${PV} == "9999" ]] ; then
EGIT_REPO_URI="git://www.evefit.org/pyfa.git"
inherit git
SRC_URI=""
else
SRC_URI="http://dl.evefit.org/stable/${PN}-${PV}-stable-RC1-src.tar.bz2"
fi
DESCRIPTION="PyFa is a EVE Online fitting tool application for GNU/Linux systems"
HOMEPAGE="http://evefit.org/Pyfa"
KEYWORDS="~x86 ~amd64"
SLOT="0"
LICENSE="GPL-3"
IUSE=""
DEPEND="
dev-python/sqlalchemy
dev-python/wxpython
dev-python/matplotlib
dev-python/numpy
"
RDEPEND="${DEPEND}"

1
profiles/repo_name Normal file
View File

@ -0,0 +1 @@
quarks_gentoo_hardened_overlay

8
x11-drivers/nvidia-drivers/Manifest Normal file
View File

@ -0,0 +1,8 @@
AUX 256.35-unified-arch.patch 1380 RMD160 2612cad105f442d4232b99e3054124e8037860bb SHA1 d82433c0b3520c87e05f1013a59b243ec65ebe97 SHA256 5e84bb51e0f9b3ceba270d53ad2a739dc534861df9acd6ab6852670f5a1357d7
AUX nvidia-169.07 639 RMD160 8baddb6fd1bf7f0e2688870a78e8ace051d62e3f SHA1 b30487ba2a24a6b1359d1fd831eeb1705060953c SHA256 a8c4860f008d53776fda7a17b59524f271236559af688e9a2c9845cbbcba1577
AUX nvidia-drivers-275.19-pax-const.patch 833 RMD160 100c36ed4c7db0f30c0680b276a708cd5ed75749 SHA1 b336665366340fec6bd400f36d3e4b9de86473f5 SHA256 74ba8aa3b03e1b4a0515fd84c159eaeb7635fa1364e77544b01ff6f571f0e6d8
AUX nvidia-drivers-285.03-pax-usercopy.patch 2043 RMD160 08453cfed4d50622709f47bdce44ad7c828ad5d1 SHA1 374b228cb7ae766f4c19875a5d8395f2da7d63f8 SHA256 8b0055fd6ba86531f968ee67f3c026d6fda05f0f3288371f23c4c5cc34ca53de
DIST NVIDIA-FreeBSD-x86-285.03.tar.gz 30736992 RMD160 96e35fb251a65b27d8aa358bdc9d814e8fd90f72 SHA1 cfc4ce1b864580dc7221a479ba48fb798af4551d SHA256 872de331825e8d0326785a5559e49cd34b5c902be8a2f43cc4c342511807e30b
DIST NVIDIA-Linux-x86-285.03.run 33556616 RMD160 0b44943a1eea4c44ccf252ad92814665355deb95 SHA1 2487321c609679980bd63ce91a058d29d7175c9b SHA256 4cdc31f0edfa3e8cc67fb3d0388d908fb22f9505a1066ce1be79820cbc93b4f8
DIST NVIDIA-Linux-x86_64-285.03.run 56689227 RMD160 d8f387619d70bf9535c87370376622b5bd3fc94e SHA1 f301677f66d7d92d11654c8ec97a3c8d53ae429f SHA256 fc1e895635b9ea7171f4e7c549e6502f3853838cb4cc254a190b004579a1f919
EBUILD nvidia-drivers-285.03.ebuild 16749 RMD160 2ec13b28ccc191e337320680934bfdc030d59eae SHA1 1c942abb11251e5e45f87966a39d0b2aae559f6e SHA256 04a8e5adaffdce102f1c4c01a61b47e92ed02da55eea49445784c4cd6687a164

31
x11-drivers/nvidia-drivers/files/256.35-unified-arch.patch Normal file
View File

@ -0,0 +1,31 @@
Add support for the 'x86' unified kernel arch in conftest.sh
--- NVIDIA-Linux-x86-256.25/kernel/conftest.sh
+++ NVIDIA-Linux-x86-256.25/kernel/conftest.sh
@@ -101,7 +101,7 @@ build_cflags() {
if [ "$OUTPUT" != "$SOURCES" ]; then
MACH_CFLAGS="-I$HEADERS/asm-$ARCH/mach-default"
- if [ "$ARCH" = "i386" -o "$ARCH" = "x86_64" ]; then
+ if [ "$ARCH" = "i386" -o "$ARCH" = "x86_64" -o "$ARCH" = "x86" ]; then
MACH_CFLAGS="$MACH_CFLAGS -I$HEADERS/asm-x86/mach-default"
MACH_CFLAGS="$MACH_CFLAGS -I$SOURCES/arch/x86/include/asm/mach-default"
fi
@@ -110,7 +110,7 @@ build_cflags() {
fi
else
MACH_CFLAGS="-I$HEADERS/asm/mach-default"
- if [ "$ARCH" = "i386" -o "$ARCH" = "x86_64" ]; then
+ if [ "$ARCH" = "i386" -o "$ARCH" = "x86_64" -o "$ARCH" = "x86" ]; then
MACH_CFLAGS="$MACH_CFLAGS -I$HEADERS/asm-x86/mach-default"
MACH_CFLAGS="$MACH_CFLAGS -I$SOURCES/arch/x86/include/asm/mach-default"
fi
@@ -121,7 +121,7 @@ build_cflags() {
CFLAGS="$BASE_CFLAGS $MACH_CFLAGS $OUTPUT_CFLAGS -I$HEADERS $AUTOCONF_CFLAGS"
- if [ "$ARCH" = "i386" -o "$ARCH" = "x86_64" ]; then
+ if [ "$ARCH" = "i386" -o "$ARCH" = "x86_64" -o "$ARCH" = "x86" ]; then
CFLAGS="$CFLAGS -I$SOURCES/arch/x86/include"
fi
if [ -n "$BUILD_PARAMS" ]; then

14
x11-drivers/nvidia-drivers/files/nvidia-169.07 Normal file
View File

@ -0,0 +1,14 @@
# Nvidia drivers support
alias char-major-195 nvidia
alias /dev/nvidiactl char-major-195
# To tweak the driver the following options can be used, note that
# you should be careful, as it could cause instability!! For more
# options see /usr/share/doc/PACKAGE/README
#
# !!! SECURITY WARNING !!!
# DO NOT MODIFY OR REMOVE THE DEVICE FILE RELATED OPTIONS UNLESS YOU KNOW
# WHAT YOU ARE DOING.
# ONLY ADD TRUSTED USERS TO THE VIDEO GROUP, THESE USERS MAY BE ABLE TO CRASH,
# COMPROMISE, OR IRREPARABLY DAMAGE THE MACHINE.
options nvidia NVreg_DeviceFileMode=432 NVreg_DeviceFileUID=0 NVreg_DeviceFileGID=VIDEOGID NVreg_ModifyDeviceFiles=1

17
x11-drivers/nvidia-drivers/files/nvidia-drivers-275.19-pax-const.patch Normal file
View File

@ -0,0 +1,17 @@
Binary files kernel.orig/.nv-procfs.c.swp and kernel/.nv-procfs.c.swp differ
diff -urp kernel.orig/nv-procfs.c kernel/nv-procfs.c
--- kernel.orig/nv-procfs.c 2011-07-13 03:29:30.000000000 +0200
+++ kernel/nv-procfs.c 2011-07-19 15:45:27.982993911 +0200
@@ -707,8 +707,10 @@ int nv_register_procfs(void)
* However, in preparation for this, we need to preserve
* the procfs read() and write() operations.
*/
- nv_procfs_registry_fops.read = entry->proc_fops->read;
- nv_procfs_registry_fops.write = entry->proc_fops->write;
+ pax_open_kernel();
+ *(void **)&nv_procfs_registry_fops.read = entry->proc_fops->read;
+ *(void **)&nv_procfs_registry_fops.write = entry->proc_fops->write;
+ pax_close_kernel();
entry = NV_CREATE_PROC_FILE("registry", proc_nvidia,
nv_procfs_read_registry,

43
x11-drivers/nvidia-drivers/files/nvidia-drivers-285.03-pax-usercopy.patch Normal file
View File

@ -0,0 +1,43 @@
--- nvidia-drivers-285.03/kernel/nv-linux.h.orig 2011-09-28 18:42:55.523481694 -0700
+++ nvidia-drivers-285.03/kernel/nv-linux.h 2011-09-28 18:44:04.411481685 -0700
@@ -695,16 +695,16 @@
#if defined(NV_KMEM_CACHE_CREATE_PRESENT)
#if (NV_KMEM_CACHE_CREATE_ARGUMENT_COUNT == 6)
-#define NV_KMEM_CACHE_CREATE(kmem_cache, name, type) \
+#define NV_KMEM_CACHE_CREATE(kmem_cache, name, type, flags) \
{ \
kmem_cache = kmem_cache_create(name, sizeof(type), \
- 0, 0, NULL, NULL); \
+ 0, flags, NULL, NULL); \
}
#elif (NV_KMEM_CACHE_CREATE_ARGUMENT_COUNT == 5)
-#define NV_KMEM_CACHE_CREATE(kmem_cache, name, type) \
+#define NV_KMEM_CACHE_CREATE(kmem_cache, name, type, flags) \
{ \
kmem_cache = kmem_cache_create(name, sizeof(type), \
- 0, 0, NULL); \
+ 0, flags, NULL); \
}
#else
#error "NV_KMEM_CACHE_CREATE_ARGUMENT_COUNT value unrecognized!"
--- nvidia-drivers-275.09.07/kernel/nv.c 2011-06-09 00:42:32.000000000 +0200
+++ nvidia-drivers-275.09.07-patched/kernel//nv.c 2011-06-24 12:52:19.912000190 +0200
@@ -1103,7 +1103,7 @@ static int __init nvidia_init_module(voi
NV_SPIN_LOCK_INIT(&km_lock);
#endif
- NV_KMEM_CACHE_CREATE(nv_stack_t_cache, "nv_stack_t", nv_stack_t);
+ NV_KMEM_CACHE_CREATE(nv_stack_t_cache, "nv_stack_t", nv_stack_t, SLAB_USERCOPY);
if (nv_stack_t_cache == NULL)
{
nv_printf(NV_DBG_ERRORS, "NVRM: stack cache allocation failed!\n");
@@ -1218,7 +1218,7 @@ static int __init nvidia_init_module(voi
}
#endif
- NV_KMEM_CACHE_CREATE(nv_pte_t_cache, "nv_pte_t", nv_pte_t);
+ NV_KMEM_CACHE_CREATE(nv_pte_t_cache, "nv_pte_t", nv_pte_t, 0);
if (nv_pte_t_cache == NULL)
{
rc = -ENOMEM;

547
x11-drivers/nvidia-drivers/nvidia-drivers-285.03.ebuild Normal file
View File

@ -0,0 +1,547 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-drivers/nvidia-drivers/nvidia-drivers-285.03.ebuild,v 1.1 2011/09/13 15:22:54 cardoe Exp $
EAPI="2"
inherit eutils multilib versionator linux-mod flag-o-matic nvidia-driver
X86_NV_PACKAGE="NVIDIA-Linux-x86-${PV}"
AMD64_NV_PACKAGE="NVIDIA-Linux-x86_64-${PV}"
X86_FBSD_NV_PACKAGE="NVIDIA-FreeBSD-x86-${PV}"
DESCRIPTION="NVIDIA X11 driver and GLX libraries"
HOMEPAGE="http://www.nvidia.com/"
SRC_URI="x86? ( http://us.download.nvidia.com/XFree86/Linux-x86/${PV}/${X86_NV_PACKAGE}.run )
amd64? ( http://us.download.nvidia.com/XFree86/Linux-x86_64/${PV}/${AMD64_NV_PACKAGE}.run )
x86-fbsd? ( http://us.download.nvidia.com/XFree86/FreeBSD-x86/${PV}/${X86_FBSD_NV_PACKAGE}.tar.gz )"
LICENSE="NVIDIA"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86 ~x86-fbsd"
IUSE="acpi custom-cflags gtk multilib kernel_linux hardened"
RESTRICT="strip"
EMULTILIB_PKG="true"
COMMON="<x11-base/xorg-server-1.10.99
kernel_linux? ( >=sys-libs/glibc-2.6.1 )
multilib? ( app-emulation/emul-linux-x86-xlibs )
>=app-admin/eselect-opengl-1.0.9
!<media-video/nvidia-settings-256.52"
DEPEND="${COMMON}
kernel_linux? ( virtual/linux-sources )"
RDEPEND="${COMMON}
x11-libs/libXvMC
acpi? ( sys-power/acpid )"
PDEPEND=">=x11-libs/libvdpau-0.3-r1
gtk? ( media-video/nvidia-settings )"
QA_TEXTRELS_x86="
usr/lib/libOpenCL.so.1.0.0
usr/lib/libXvMCNVIDIA.so.${PV}
usr/lib/libcuda.so.${PV}
usr/lib/libnvcuvid.so.${PV}
usr/lib/libnvidia-cfg.so.${PV}
usr/lib/libnvidia-compiler.so.${PV}
usr/lib/libnvidia-glcore.so.${PV}
usr/lib/libnvidia-ml.so.${PV}
usr/lib/libvdpau_nvidia.so.${PV}
usr/lib/opengl/nvidia/extensions/libglx.so.${PV}
usr/lib/opengl/nvidia/lib/libGL.so.${PV}
usr/lib/opengl/nvidia/lib/libnvidia-tls.so.${PV}
usr/lib/xorg/modules/drivers/nvidia_drv.so"
QA_TEXTRELS_x86_fbsd="boot/modules/nvidia.ko
usr/lib/opengl/nvidia/lib/libGL.so.1
usr/lib/libnvidia-glcore.so.1
usr/lib/libnvidia-cfg.so.1
usr/lib/libnvidia-ml.so.1
usr/lib/opengl/nvidia/extensions/libglx.so.1
usr/lib/xorg/modules/drivers/nvidia_drv.so"
QA_TEXTRELS_amd64="usr/lib32/opengl/nvidia/lib/libnvidia-tls.so.${PV}
usr/lib32/libnvidia-glcore.so.${PV}
usr/lib32/opengl/nvidia/lib/libGL.so.${PV}
usr/lib32/libcuda.so.${PV}
usr/lib32/libvdpau_nvidia.so.${PV}
usr/lib32/libOpenCL.so.1.0.0
usr/lib32/libnvidia-compiler.so.${PV}"
QA_EXECSTACK_x86="usr/lib/opengl/nvidia/lib/libGL.so.${PV}
usr/lib/libnvidia-glcore.so.${PV}
usr/lib/opengl/nvidia/extensions/libglx.so.${PV}
usr/lib64/libXvMCNVIDIA.so.${PV}
usr/lib/libXvMCNVIDIA.a:NVXVMC.o
usr/lib/libnvidia-compiler.so.${PV}
usr/lib/libvdpau_nvidia.so.${PV}
usr/lib/libcuda.so.${PV}
usr/lib/libOpenCL.so.1.0.0"
QA_EXECSTACK_amd64="usr/lib32/libnvidia-glcore.so.${PV}
usr/lib32/opengl/nvidia/lib/libGL.so.${PV}
usr/lib32/libnvidia-compiler.so.${PV}
usr/lib32/opengl/nvidia/lib/libnvidia-tls.so.${PV}
usr/lib32/libvdpau_nvidia.so.${PV}
usr/lib32/libcuda.so.${PV}
usr/lib32/libOpenCL.so.1.0.0
usr/lib64/libnvidia-compiler.so.${PV}
usr/lib64/libXvMCNVIDIA.a:NVXVMC.o
usr/lib64/libnvidia-cfg.so.${PV}
usr/lib64/libnvidia-ml.so.${PV}
usr/lib64/libvdpau_nvidia.so.${PV}
usr/lib64/opengl/nvidia/lib/libnvidia-tls.so.${PV}
usr/lib64/opengl/nvidia/lib/libGL.so.${PV}
usr/lib64/libnvidia-glcore.so.${PV}
usr/lib64/opengl/nvidia/extensions/libglx.so.${PV}
usr/lib64/libXvMCNVIDIA.so.${PV}
usr/lib64/libcuda.so.${PV}
usr/lib64/libOpenCL.so.1.0.0
usr/lib64/xorg/modules/drivers/nvidia_drv.so
usr/bin/nvidia-smi
usr/bin/nvidia-xconfig
usr/bin/nvidia-settings"
QA_WX_LOAD_x86="usr/lib/libnvidia-glcore.so.${PV}
usr/lib/opengl/nvidia/lib/libGL.so.${PV}
usr/lib/opengl/nvidia/extensions/libglx.so.${PV}
usr/lib/libXvMCNVIDIA.a
usr/lib64/libXvMCNVIDIA.so.${PV}"
QA_WX_LOAD_amd64="usr/lib32/opengl/nvidia/lib/libGL.so.${PV}
usr/lib32/libnvidia-glcore.so.${PV}
usr/lib64/opengl/nvidia/lib/libGL.so.${PV}
usr/lib64/libnvidia-glcore.so.${PV}
usr/lib64/opengl/nvidia/extensions/libglx.so.${PV}
usr/lib64/libXvMCNVIDIA.so.${PV}"
QA_SONAME_x86="usr/lib/libnvidia-compiler.so.${PV}"
QA_SONAME_amd64="usr/lib64/libnvidia-compiler.so.${PV}
usr/lib32/libnvidia-compiler.so.${PV}"
QA_DT_HASH_amd64="usr/lib32/libcuda.so.${PV}
usr/lib32/opengl/nvidia/lib/libGL.so.${PV}
usr/lib32/libnvidia-glcore.so.${PV}
usr/lib32/opengl/nvidia/lib/libnvidia-tls.so.${PV}
usr/lib32/libvdpau_nvidia.so.${PV}
usr/lib32/libOpenCL.so.1.0.0
usr/lib32/libnvidia-compiler.so.${PV}
usr/lib64/libXvMCNVIDIA.so.${PV}
usr/lib64/libcuda.so.${PV}
usr/lib64/libnvidia-cfg.so.${PV}
usr/lib64/libnvidia-glcore.so.${PV}
usr/lib64/libnvidia-ml.so.${PV}
usr/lib64/opengl/nvidia/lib/libGL.so.${PV}
usr/lib64/opengl/nvidia/lib/libnvidia-tls.so.${PV}
usr/lib64/opengl/nvidia/extensions/libglx.so.${PV}
usr/lib64/xorg/modules/drivers/nvidia_drv.so
usr/lib64/libvdpau_nvidia.so.${PV}
usr/lib64/libOpenCL.so.1.0.0
usr/lib64/libnvidia-compiler.so.${PV}
usr/lib64/libnvcuvid.so.${PV}
usr/bin/nvidia-smi
usr/bin/nvidia-xconfig
usr/bin/nvidia-settings"
QA_DT_HASH_x86="usr/lib/libcuda.so.${PV}
usr/lib/libnvidia-cfg.so.${PV}
usr/lib/libnvidia-glcore.so.${PV}
usr/lib/libnvidia-ml.so.${PV}
usr/lib/opengl/nvidia/lib/libGL.so.${PV}
usr/lib/opengl/nvidia/lib/libnvidia-tls.so.${PV}
usr/lib/opengl/nvidia/extensions/libglx.so.${PV}
usr/lib/xorg/modules/drivers/nvidia_drv.so
usr/lib/libXvMCNVIDIA.so.${PV}
usr/lib/libvdpau_nvidia.so.${PV}
usr/lib/libOpenCL.so.1.0.0
usr/lib/libnvidia-compiler.so.${PV}
usr/lib/libnvcuvid.so.${PV}
usr/bin/nvidia-smi
usr/bin/nvidia-xconfig
usr/bin/nvidia-settings"
S="${WORKDIR}/"
mtrr_check() {
ebegin "Checking for MTRR support"
linux_chkconfig_present MTRR
eend $?
if [[ $? -ne 0 ]] ; then
eerror "Please enable MTRR support in your kernel config, found at:"
eerror
eerror " Processor type and features"
eerror " [*] MTRR (Memory Type Range Register) support"
eerror
eerror "and recompile your kernel ..."
die "MTRR support not detected!"
fi
}
lockdep_check() {
if linux_chkconfig_present LOCKDEP; then
eerror "You've enabled LOCKDEP -- lock tracking -- in the kernel."
eerror "Unfortunately, this option exports the symbol "
eerror "'lockdep_init_map' as GPL-only which will prevent "
eerror "${P} from compiling."
eerror "Please make sure the following options have been unset:"
eerror
eerror " Kernel hacking --->"
eerror " [ ] Lock debugging: detect incorrect freeing of live locks"
eerror " [ ] Lock debugging: prove locking correctness"
eerror " [ ] Lock usage statistics"
eerror "in 'menuconfig'"
die "LOCKDEP enabled"
fi
}
pkg_setup() {
# try to turn off distcc and ccache for people that have a problem with it
export DISTCC_DISABLE=1
export CCACHE_DISABLE=1
if use amd64 && has_multilib_profile && [ "${DEFAULT_ABI}" != "amd64" ]; then
eerror "This ebuild doesn't currently support changing your default abi."
die "Unexpected \${DEFAULT_ABI} = ${DEFAULT_ABI}"
fi
if use kernel_linux; then
linux-mod_pkg_setup
MODULE_NAMES="nvidia(video:${S}/kernel)"
BUILD_PARAMS="IGNORE_CC_MISMATCH=yes V=1 SYSSRC=${KV_DIR} \
SYSOUT=${KV_OUT_DIR} CC=$(tc-getBUILD_CC)"
mtrr_check
lockdep_check
fi
# On BSD userland it wants real make command
use userland_BSD && MAKE="$(get_bmake)"
export _POSIX2_VERSION="199209"
# Since Nvidia ships 3 different series of drivers, we need to give the user
# some kind of guidance as to what version they should install. This tries
# to point the user in the right direction but can't be perfect. check
# nvidia-driver.eclass
nvidia-driver-check-warning
# set variables to where files are in the package structure
if use kernel_FreeBSD; then
NV_DOC="${S}/doc"
NV_EXEC="${S}/obj"
NV_LIB="${S}/obj"
NV_SRC="${S}/src"
NV_MAN="${S}/x11/man"
NV_X11="${S}/obj"
NV_X11_DRV="${NV_X11}"
NV_X11_EXT="${NV_X11}"
NV_SOVER=1
elif use kernel_linux; then
NV_DOC="${S}"
NV_EXEC="${S}"
NV_LIB="${S}"
NV_SRC="${S}/kernel"
NV_MAN="${S}"
NV_X11="${S}"
NV_X11_DRV="${NV_X11}"
NV_X11_EXT="${NV_X11}"
NV_SOVER=${PV}
else
die "Could not determine proper NVIDIA package"
fi
}
src_unpack() {
if use kernel_linux && kernel_is lt 2 6 7; then
echo
ewarn "Your kernel version is ${KV_MAJOR}.${KV_MINOR}.${KV_PATCH}"
ewarn "This is not officially supported for ${P}. It is likely you"
ewarn "will not be able to compile or use the kernel module."
ewarn "It is recommended that you upgrade your kernel to a version >= 2.6.7"
echo
ewarn "DO NOT file bug reports for kernel versions less than 2.6.7 as they will be ignored."
fi
if ! use x86-fbsd; then
cd "${S}"
unpack_makeself
else
unpack ${A}
fi
}
src_prepare() {
# Please add a brief description for every added patch
use x86-fbsd && cd doc
if use kernel_linux; then
# Quiet down warnings the user does not need to see
sed -i \
-e 's:-Wsign-compare::g' \
"${NV_SRC}"/Makefile.kbuild
epatch "${FILESDIR}"/256.35-unified-arch.patch
# If you set this then it's your own fault when stuff breaks :)
use custom-cflags && sed -i "s:-O:${CFLAGS}:" "${NV_SRC}"/Makefile.*
# If greater than 2.6.5 use M= instead of SUBDIR=
convert_to_m "${NV_SRC}"/Makefile.kbuild
fi
if use hardened; then
epatch "${FILESDIR}"/nvidia-drivers-275.19-pax-const.patch
# epatch "${FILESDIR}"/nvidia-drivers-285.03-pax-usercopy.patch
fi
}
src_compile() {
# This is already the default on Linux, as there's no toplevel Makefile, but
# on FreeBSD there's one and triggers the kernel module build, as we install
# it by itself, pass this.
cd "${NV_SRC}"
if use x86-fbsd; then
MAKE="$(get_bmake)" CFLAGS="-Wno-sign-compare" emake CC="$(tc-getCC)" \
LD="$(tc-getLD)" LDFLAGS="$(raw-ldflags)" || die
elif use kernel_linux; then
linux-mod_src_compile
fi
}
src_install() {
if use kernel_linux; then
linux-mod_src_install
VIDEOGROUP="$(egetent group video | cut -d ':' -f 3)"
if [ -z "$VIDEOGROUP" ]; then
eerror "Failed to determine the video group gid."
die "Failed to determine the video group gid."
fi
# Add the aliases
[ -f "${FILESDIR}/nvidia-169.07" ] || die "nvidia missing in FILESDIR"
sed -e 's:PACKAGE:'${PF}':g' \
-e 's:VIDEOGID:'${VIDEOGROUP}':' "${FILESDIR}"/nvidia-169.07 > \
"${WORKDIR}"/nvidia
insinto /etc/modprobe.d
newins "${WORKDIR}"/nvidia nvidia.conf || die
elif use x86-fbsd; then
insinto /boot/modules
doins "${WORKDIR}/${NV_PACKAGE}/src/nvidia.kld" || die
exeinto /boot/modules
doexe "${WORKDIR}/${NV_PACKAGE}/src/nvidia.ko" || die
fi
# NVIDIA kernel <-> userspace driver config lib
dolib.so ${NV_LIB}/libnvidia-cfg.so.${NV_SOVER} || \
die "failed to install libnvidia-cfg"
dosym /usr/$(get_libdir)/libnvidia-cfg.so.${NV_SOVER} \
/usr/$(get_libdir)/libnvidia-cfg.so || \
die "failed to create libnvidia-cfg.so symlink"
# NVIDIA monitoring library
dolib.so ${NV_LIB}/libnvidia-ml.so.${NV_SOVER} || \
die "failed to install libnvidia-ml"
dosym /usr/$(get_libdir)/libnvidia-ml.so.${NV_SOVER} \
/usr/$(get_libdir)/libnvidia-ml.so || \
die "failed to create libnvidia-ml.so symlink"
# NVIDIA video decode <-> CUDA
dolib.so ${NV_LIB}/libnvcuvid.so.${NV_SOVER} || \
die "failed to install libnvcuvid.so"
dosym /usr/$(get_libdir)/libnvcuvid.so.${NV_SOVER} \
/usr/$(get_libdir)/libnvcuvid.so || \
die "failed to create libnvcuvid.so symlink"
# Xorg DDX driver
insinto /usr/$(get_libdir)/xorg/modules/drivers
doins ${NV_X11_DRV}/nvidia_drv.so || die "failed to install nvidia_drv.so"
# Xorg GLX driver
insinto /usr/$(get_libdir)/opengl/nvidia/extensions
doins ${NV_X11_EXT}/libglx.so.${NV_SOVER} || \
die "failed to install libglx.so"
dosym /usr/$(get_libdir)/opengl/nvidia/extensions/libglx.so.${NV_SOVER} \
/usr/$(get_libdir)/opengl/nvidia/extensions/libglx.so || \
die "failed to create libglx.so symlink"
# XvMC driver
dolib.a ${NV_X11}/libXvMCNVIDIA.a || \
die "failed to install libXvMCNVIDIA.so"
dolib.so ${NV_X11}/libXvMCNVIDIA.so.${NV_SOVER} || \
die "failed to install libXvMCNVIDIA.so"
dosym libXvMCNVIDIA.so.${NV_SOVER} /usr/$(get_libdir)/libXvMCNVIDIA.so || \
die "failed to create libXvMCNVIDIA.so symlink"
# OpenCL ICD for NVIDIA
if use kernel_linux; then
dodir /etc/OpenCL/vendors
insinto /etc/OpenCL/vendors
doins nvidia.icd
fi
# Documentation
dohtml ${NV_DOC}/html/*
if use x86-fbsd; then
dodoc "${NV_DOC}/README"
doman "${NV_MAN}/nvidia-xconfig.1"
use gtk && doman "${NV_MAN}/nvidia-settings.1"
else
# Docs
newdoc "${NV_DOC}/README.txt" README
dodoc "${NV_DOC}/NVIDIA_Changelog"
doman "${NV_MAN}/nvidia-smi.1.gz"
doman "${NV_MAN}/nvidia-xconfig.1.gz"
use gtk && doman "${NV_MAN}/nvidia-settings.1.gz"
fi
# Helper Apps
dobin ${NV_EXEC}/nvidia-xconfig || die
if use gtk; then
dobin ${NV_EXEC}/nvidia-settings || die
fi
dobin ${NV_EXEC}/nvidia-bug-report.sh || die
if use kernel_linux; then
dobin ${NV_EXEC}/nvidia-smi || die
fi
# Desktop entries for nvidia-settings
if use gtk; then
sed -e 's:__UTILS_PATH__:/usr/bin:' \
-e 's:__PIXMAP_PATH__:/usr/share/pixmaps:' \
-i "${NV_EXEC}/nvidia-settings.desktop"
domenu ${NV_EXEC}/nvidia-settings.desktop
doicon ${NV_EXEC}/nvidia-settings.png
fi
if has_multilib_profile ; then
local OABI=${ABI}
for ABI in $(get_install_abis) ; do
src_install-libs
done
ABI=${OABI}
unset OABI
else
src_install-libs
fi
is_final_abi || die "failed to iterate through all ABIs"
}
# Install nvidia library:
# the first parameter is the place where to install it
# the second parameter is the base name of the library
# the third parameter is the provided soversion
donvidia() {
dodir $1
exeinto $1
libname=$(basename $2)
doexe $2.$3 || die "failed to install $2"
dosym ${libname}.$3 $1/${libname} || die "failed to symlink $2"
[[ $3 != "1" ]] && dosym ${libname}.$3 $1/${libname}.1
}
src_install-libs() {
local inslibdir=$(get_libdir)
local NV_ROOT="/usr/${inslibdir}/opengl/nvidia"
local libdir= sover=
if use kernel_linux; then
if has_multilib_profile && [[ ${ABI} == "x86" ]] ; then
libdir=32
else
libdir=.
fi
sover=${PV}
else
libdir=obj
# on FreeBSD it has just .1 suffix
sover=1
fi
# The GLX libraries
donvidia ${NV_ROOT}/lib ${libdir}/libGL.so ${sover}
donvidia /usr/${inslibdir} ${libdir}/libnvidia-glcore.so ${sover}
if use x86-fbsd; then
donvidia ${NV_ROOT}/lib ${libdir}/libnvidia-tls.so ${sover}
else
donvidia ${NV_ROOT}/lib ${libdir}/tls/libnvidia-tls.so ${sover}
fi
# VDPAU
donvidia /usr/${inslibdir} ${libdir}/libvdpau_nvidia.so ${sover}
# CUDA & OpenCL
if use kernel_linux; then
donvidia /usr/${inslibdir} ${libdir}/libcuda.so ${sover}
donvidia /usr/${inslibdir} ${libdir}/libnvidia-compiler.so ${sover}
donvidia /usr/${inslibdir} ${libdir}/libOpenCL.so 1.0.0
dosym libOpenCL.so.1 /usr/${inslibdir}/libOpenCL.so
fi
}
pkg_preinst() {
if use kernel_linux; then
linux-mod_pkg_postinst
fi
# Clean the dynamic libGL stuff's home to ensure
# we dont have stale libs floating around
if [ -d "${ROOT}"/usr/lib/opengl/nvidia ] ; then
rm -rf "${ROOT}"/usr/lib/opengl/nvidia/*
fi
# Make sure we nuke the old nvidia-glx's env.d file
if [ -e "${ROOT}"/etc/env.d/09nvidia ] ; then
rm -f "${ROOT}"/etc/env.d/09nvidia
fi
}
pkg_postinst() {
if use kernel_linux; then
linux-mod_pkg_postinst
fi
# Switch to the nvidia implementation
eselect opengl set --use-old nvidia
echo
elog "You must be in the video group to use the NVIDIA device"
elog "For more info, read the docs at"
elog "http://www.gentoo.org/doc/en/nvidia-guide.xml#doc_chap3_sect6"
elog
elog "This ebuild installs a kernel module and X driver. Both must"
elog "match explicitly in their version. This means, if you restart"
elog "X, you must modprobe -r nvidia before starting it back up"
elog
elog "To use the NVIDIA GLX, run \"eselect opengl set nvidia\""
elog
elog "NVIDIA has requested that any bug reports submitted have the"
elog "output of /usr/bin/nvidia-bug-report.sh included."
elog
elog "To work with compiz, you must enable the AddARGBGLXVisuals option."
elog
elog "If you are having resolution problems, try disabling DynamicTwinView."
elog
if ! use gtk; then
elog "USE=gtk controls whether the nvidia-settings application"
elog "is installed. If you would like to use it, enable that"
elog "flag and re-emerge this ebuild. media-video/nvidia-settings"
elog "no longer installs nvidia-settings but only installs the"
elog "associated user space libraries."
fi
}
pkg_postrm() {
if use kernel_linux; then
linux-mod_pkg_postrm
fi
eselect opengl set --use-old xorg-x11
}

2
x11-misc/cairo-dock-plugins/Manifest Normal file
View File

@ -0,0 +1,2 @@
DIST cairo-dock-plugins-2.2.0-4.tar.gz 5533523 RMD160 33e6ad6831e66d9da5ad313210913f9d81138502 SHA1 1873ae26a1d90f8ac3cfde665536eca5dab7645f SHA256 e8905dc6f397c89b53b6e6a15489bf4d78e19427bd95e01f7c1b3df21a564ce2
EBUILD cairo-dock-plugins-2.2.0.4.ebuild 2440 RMD160 02c78725056ae8bb2080d4422e885df712a41e11 SHA1 62ffbf7beb76849915d915093341805e5d2227e9 SHA256 23d647594c00682c352fbcb8ebcd7a3e553218a89cdf4f1bd1c28164e8f6cad1

90
x11-misc/cairo-dock-plugins/cairo-dock-plugins-2.2.0.4.ebuild Normal file
View File

@ -0,0 +1,90 @@
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
EAPI="2"
inherit cmake-utils eutils versionator
MY_PN="${PN/plugins/plug-ins}"
MY_PV=$(replace_version_separator 3 '-')
MM_PV=$(get_version_component_range '1-2')
MMD_PV=$(get_version_component_range '1-3')
DESCRIPTION="Official plugins for cairo-dock"
HOMEPAGE="https://launchpad.net/cairo-dock-plug-ins/"
SRC_URI="http://launchpad.net/${MY_PN}/${MM_PV}/${MMD_PV}/+download/${PN}-${MY_PV}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE="alsa compiz exif gio gmenu gnome kde mail musicplayer network-monitor powermanager terminal tomboy webkit wifi xfce xgamma xklavier"
# "dbus-glib-1"
# "gthread-2.0" - glib
# "libxml-2.0"
# "librsvg-2.0"
# "dbus-1"
# "cairo"
# "gtk+-2.0"
# "gtkglext-1.0"
# "cairo-dock"
RDEPEND="
dev-libs/dbus-glib
dev-libs/glib:2
dev-libs/libxml2
gnome-base/librsvg
sys-apps/dbus
x11-libs/cairo
x11-libs/gtk+:2
x11-libs/gtkglext
~x11-misc/cairo-dock-${PV}
alsa? ( media-libs/alsa-lib )
exif? ( media-libs/libexif )
gmenu? ( gnome-base/gnome-menus )
kde? ( kde-base/kdelibs )
terminal? ( x11-libs/vte )
webkit? ( >=net-libs/webkit-gtk-1.0 )
xfce? ( xfce-base/thunar )
xgamma? ( x11-libs/libXxf86vm )
xklavier? ( x11-libs/libxklavier )
"
DEPEND="${RDEPEND}
dev-util/intltool
sys-devel/gettext
dev-util/pkgconfig
"
S="${WORKDIR}/${PN}-${MY_PV}"
# Additional config options
#dnd2share
#rssreader
#xrandr-in-show-desktop
#scooby-do
#src_configure() {
# econf --disable-dependency-tracking \
# --disable-old-gnome-integration \
# $(use_enable alsa alsa-mixer) \
# $(use_enable compiz compiz-icon) \
# $(use_enable exif) \
# $(use_enable gio gio-in-gmenu) \
# $(use_enable gio gmenu) \
# $(use_enable gmenu) \
# $(use_enable gnome gnome-integration) \
# $(use_enable kde kde-integration) \
# $(use_enable mail) \
# $(use_enable musicplayer) \
# $(use_enable network-monitor) \
# $(use_enable powermanager) \
# $(use_enable terminal) \
# $(use_enable tomboy) \
# $(use_enable webkit weblets) \
# $(use_enable wifi) \
# $(use_enable xfce xfce-integration) \
# $(use_enable xgamma) \
# $(use_enable xklavier keyboard-indicator)
#}

3
x11-misc/cairo-dock/Manifest Normal file
View File

@ -0,0 +1,3 @@
AUX cairo-dock-2.2.0.4-rpath.patch 553 RMD160 3d22935978ea90b8629a9527cf55861e6bf1b9e7 SHA1 9682d118974e06b0f2754b797b5a84e525f257c3 SHA256 4f80c8aabd51c5ad67353676baaced276e5350cc2b97a601a22675a0b1edd467
DIST cairo-dock-2.2.0-4.tar.gz 2335519 RMD160 23d0917e5b0c49790b7b5f266d40b837af555bd2 SHA1 4edc1d4f71d71b5c7cf295bdcc4b40bc016bc54e SHA256 dc2de939e8fe8bb2b020d7c12c106114f321a104ea41d3538fbc1fce2fadff95
EBUILD cairo-dock-2.2.0.4.ebuild 1708 RMD160 d7c55b03ab87bb560a676f7ee09036ec47dbbbe3 SHA1 f05f441ee356d7e49351eccb8ecde0e5193731e8 SHA256 208769e6bf9d3fadf4041a20f074aca38dd608d0b5a13fdc1762b803a4c32b93

75
x11-misc/cairo-dock/cairo-dock-2.2.0.4.ebuild Normal file
View File

@ -0,0 +1,75 @@
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
EAPI="2"
inherit cmake-utils eutils versionator
MY_PN="${PN}-core"
MY_PV=$(replace_version_separator 3 '-')
MM_PV=$(get_version_component_range '1-2')
MMD_PV=$(get_version_component_range '1-3')
DESCRIPTION="Cairo-dock is a fast, responsive, Mac OS X-like dock."
HOMEPAGE="https://launchpad.net/cairo-dock-core/"
SRC_URI="http://launchpad.net/${MY_PN}/${MM_PV}/${MMD_PV}/+download/${PN}-${MY_PV}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="xcomposite"
#"libcurl"
#"gthread-2.0"
#"dbus-glib-1"
#"libxml-2.0"
#"librsvg-2.0"
#"dbus-1"
#"cairo"
#"gtk+-2.0"
#"gtkglext-1.0"
#"xrender"
RDEPEND="
dev-libs/dbus-glib
dev-libs/glib:2
dev-libs/libxml2
gnome-base/librsvg
sys-apps/dbus
x11-libs/cairo
x11-libs/gtk+:2
x11-libs/gtkglext
x11-libs/libXrender
xcomposite? (
x11-libs/libXcomposite
x11-libs/libXinerama
x11-libs/libXtst
)
"
DEPEND="${RDEPEND}
dev-util/intltool
dev-util/pkgconfig
sys-devel/gettext
"
S="${WORKDIR}/${PN}-${MY_PV}"
src_prepare() {
epatch "${FILESDIR}/${P}-rpath.patch" || die
}
#src_configure() {
# econf $(use_enable xcomposite xextend)
#}
pkg_postinst() {
elog "Cairo-Dock is an app that draws on a RGBA GLX visual."
elog "Some users have noticed that if the dock is launched,"
elog "severals qt4-based applications could crash, like skype or vlc."
elog "If you have this problem, add the following line into your bashrc :"
echo
elog "alias vlc='export XLIB_SKIP_ARGB_VISUALS=1; vlc; unset XLIB_SKIP_ARGB_VISUALS'"
elog "see http://www.qtforum.org/article/26669/qt4-mess-up-the-opengl-context.html for more details."
}

14
x11-misc/cairo-dock/files/cairo-dock-2.2.0.4-rpath.patch Normal file
View File

@ -0,0 +1,14 @@
diff -urN cairo-dock-2.2.0-4/src/gldit/CMakeLists.txt cairo-dock-2.2.0-4-new//src/gldit/CMakeLists.txt
--- cairo-dock-2.2.0-4/src/gldit/CMakeLists.txt 2010-10-30 19:13:36.000000000 +0000
+++ cairo-dock-2.2.0-4-new//src/gldit/CMakeLists.txt 2010-10-30 19:27:45.000000000 +0000
@@ -84,9 +84,7 @@
link_directories(
${PACKAGE_LIBRARY_DIRS}
${XEXTEND_LIBRARY_DIRS}
- ${CMAKE_SOURCE_DIR}/src/gldit
- ${CMAKE_SOURCE_DIR}/src/icon-factory
- ${CMAKE_SOURCE_DIR}/src/implementations)
+ )
# Define the library
add_library ("gldi" SHARED ${core_lib_SRCS})